Trennzeichenwerte in einer SQL-Spalte in mehrere Zeilen aufteilen

Wenn Sie SQL Server 2016+ verwenden

Sie können den neuen STRING_SPLIT verwenden Funktion, über die ich hier gebloggt habe, und Brent Ozar hat hier darüber gebloggt.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Wenn Sie noch eine Version vor SQL Server 2016 verwenden

Erstellen Sie eine Split-Funktion. Dies ist nur eines von vielen Beispielen:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Ich habe ein paar andere hier, hier und einen besseren Ansatz besprochen, als hier von vornherein aufzuteilen.

Jetzt können Sie einfach extrapolieren durch:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Außerdem schlage ich vor, keine Bindestriche in Spaltennamen zu setzen. Das bedeutet, dass Sie sie immer in [square brackets] setzen müssen .