Die Umstellung ist mir gelungen. Das Knifflige dabei ist, dass es sich nicht nur um eine Mixed-Base-Conversion handelt, die höhere Base des ersten Zeichens wirkt sich auch auf die Werte längerer Codes aus.
Ich begann mit einem einfacheren Fall; Basis-10-Codes. Ich habe gesehen, dass der zweistellige Bereich 10 zusätzliche Codes hat, der dreistellige Bereich 100 zusätzliche Codes und so weiter:
0 - 9 : '0' - '9'
10 - 109 : '00' - '99'
110 - 1109 : '000' - '999'
1110 - 11109 : '0000' - '9999'
Der Wert des ersten Zeichens im Code ist also nicht nur die zur Position erhobene Basis, sondern hat auch einen Offset.
Nachdem ich dies auf die Base-62-Codierung angewendet hatte, kam ich zu folgendem Ergebnis:
create function tiny_Encode(@UrlId int) returns varchar(10)
as
begin
declare
@Chars varchar(62),
@Code varchar(10),
@Value int,
@Adder int
set @Chars = '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz'
if (@UrlId < 63) begin
set @Code = substring(@Chars, @UrlId, 1)
end else begin
set @UrlId = @UrlId - 1
set @Value = 62
set @Adder = 0
while (@UrlId >= @Value * 63 + @Adder) begin
set @Adder = @Adder + @Value
set @Value = @Value * 62
end
set @Code = substring(@Chars, (@UrlId - @Adder) / @Value, 1)
set @UrlId = ((@UrlId - @Adder) % @Value)
while (@Value > 1) begin
set @Value = @Value / 62
set @Code = @Code + substring(@Chars, @UrlId / @Value + 1, 1)
set @UrlId = @UrlId % @Value
end
end
return @Code
end
