So überprüfen Sie die Version des Oracle-Anbieters für ole-db. OraOLEDB.Oracle-Anbieter

Sie können zum Beispiel das Tool RegDllView verwenden. Suchen Sie nach „OraOLEDB“, das Ergebnis könnte dieses sein:

Ein einfacherer Ansatz wäre, zu Ihrem ORACE_HOME\bin zu navigieren Verzeichnis und suchen Sie die Datei OraOLEDB??.dll . Version prüfen mit rechter Maustaste -> Eigenschaften -> Details.

Sie erhalten jedoch nur die Version der Datei, was nicht unbedingt bedeutet, dass diese DLL auch registriert und einsatzbereit ist.

Oder verwenden Sie dieses VBScript:

Option Explicit
Const HKEY_CLASSES_ROOT = &H80000000

Dim Key, strComputer, objRegistry, strPath, arrKeys, fso
Dim strKeyPath, strValueName, strValue, uValue, ver

Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.enumKey HKEY_CLASSES_ROOT, "CLSID", arrKeys

For Each key In arrKeys
    strKeyPath = "CLSID\" & key
    strValueName = "OLEDB_SERVICES"
    If objRegistry.GetDWordValue (HKEY_CLASSES_ROOT, strKeyPath, strValueName, uValue) = 0 Then  
        'get the (Default) value which is the name of the provider
        objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", strValue
        If InStr(1, strValue, "OraOLEDB.Oracle", vbTextCompare) > 0 Then
            ' get expanded location
            objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath & "\InprocServer32", "", strPath

            ver = fso.GetFileVersion(strPath)
            Wscript.Echo strValue & " @ " & strPath & " -> " & ver
        End If
    End If 
Next

Der OLE DB-Anbieter kann in 32-Bit oder/und in 64-Bit vorhanden sein, daher können Sie das Skript zweimal ausführen:

C:\Windows\System32\cscript.exe Print_OLE.vbs
C:\Windows\SysWOW64\cscript.exe Print_OLE.vbs