Entferne ein bestimmtes Wort aus einer Zeichenfolge

Aufgrund fehlender Unterstützung für lookbehind/lookahead und Wortgrenze(\b ) In der Oracle-Implementierung von regulären Ausdrücken scheint es unmöglich zu sein, alle Anforderungen in einem einzigen REGEXP_REPLACE Anruf. Besonders für den Fall wies Egor Skriptunoff darauf hin :Musterübereinstimmungen, gefolgt von einer nach der anderen mit nur einem Trennzeichen dazwischen wie some some some some ... .

Ohne diesen Fall ist es möglich, alle derartigen Strings mit diesem Aufruf abzugleichen:

regexp_replace(
  source_string,                                       -- source string
  '([^[:alnum:]]|^)((\d)*some(\d)*)([^[:alnum:]]|$)',  -- pattern
  '\1\5',                                              -- leave separators in place
  1,                                                   -- start from beginning
  0,                                                   -- replace all occurences
  'im'                                                 -- case-insensitive and multiline 
);

Musterteile:

(                -- start of Group #1
  [^[:alnum:]]   -- any non-alphanumeric character 
  |              -- or 
  ^              -- start of string or start of line 
)                -- end of Group #1
(                -- start of Group #2
  (              -- start of Group #3 
    \d           -- any digit
  )              -- end of Group #3
  *              -- include in previous group zero or more consecutive digits
  some           -- core string to match
  (              -- start of group #4
    \d           -- any digit
  )              -- end of group #4  
  *              -- include in previous group zero or more consecutive digits
)                -- end of Group #2
(                -- start of Group #5
  [^[:alnum:]]   -- any non-alphanumeric character 
  |              -- or
  $              -- end of string or end of line
)                -- end of Group #5

Da die für den Abgleich verwendeten Trennzeichen (Gruppe Nr. 1 und Gruppe Nr. 5) im Übereinstimmungsmuster enthalten sind, werden sie bei erfolgreicher Übereinstimmung aus der Quellzeichenfolge entfernt. Daher müssen wir diese Teile wiederherstellen, indem wir im dritten regexp_replace angeben Parameter.

Basierend auf dieser Lösung ist es möglich, alle, auch sich wiederholende Vorkommnisse innerhalb einer Schleife zu ersetzen.

Beispielsweise können Sie eine Funktion wie folgt definieren:

create or replace function delete_str_with_digits(
  pSourceString in varchar2, 
  pReplacePart  in varchar2  -- base string (like 'some' in question)
)
  return varchar2
is
  C_PATTERN_START constant varchar2(100) := '([^[:alnum:]]|^)((\d)*';
  C_PATTERN_END   constant varchar2(100) := '(\d)*)([^[:alnum:]]|$)';

  vPattern         varchar2(4000);
  vCurValue        varchar2(4000);
  vPatternPosition binary_integer;
begin

  vPattern := C_PATTERN_START || pReplacePart || C_PATTERN_END;
  vCurValue := pSourceString;

  vPatternPosition := regexp_instr(vCurValue, vPattern);

  while(vPatternPosition > 0) loop
    vCurValue := regexp_replace(vCurValue, vPattern,'\1\5',1,0,'im');
    vPatternPosition := regexp_instr(vCurValue, vPattern);
  end loop;

  return vCurValue;  

end;

und verwenden Sie es mit SQL oder anderem PL/SQL-Code:

SELECT 
  delete_str_with_digits(
    'some text, -> awesome <- 123 someone, 3some3
     line of 7 :> some some some some some some some <
222some  another some1? some22 text 0some000', 
    'some'
  )  as result_string
FROM 
  dual

SQLFiddle-Beispiel