Sie scheinen in der Problembeschreibung etwas chaotisch zu sein, bitte formatieren Sie Ihre Frage und machen Sie sie lesbarer. Wie auch immer, die Lösungen sind einfach. Sie brauchen nur ein if Anweisung, wobei Sie je nach Ebene in der ersten oder zweiten Tabelle und der entsprechenden Spalte suchen:
create or replace function get_accountdetails (par_input in varchar2) return varchar2 is
v_aid varchar2(10);
v_db varchar2(10);
v_lvl varchar2(10);
v_ret varchar2(20) := '';
begin
v_aid := regexp_substr(par_input, '\d+', 1, 1);
v_db := regexp_substr(par_input, '\d+', 1, 2);
v_lvl := regexp_substr(par_input, '\d+', 1, 3);
if v_lvl = 1 then
select dim_cust_key
into v_ret
from dim_cust_acnt
where level1_account_id = v_aid and database_id = v_db;
elsif v_lvl = 2 then
select dim_cust_key
into v_ret
from dim_cust_dept
where level2_account_id = v_aid and database_id = v_db;
else
select dim_cust_key
into v_ret
from dim_cust_dept
where level3_account_id = v_aid and database_id = v_db;
end if;
return v_ret;
end;
Hier sind Tabellen und Beispielfunktionsaufrufe:
create table dim_cust_acnt (dim_cust_key, level1_account_id, database_id) as (
select 1123, 112, 22 from dual union all
select 1234, 113, 23 from dual );
create table dim_cust_dept (dim_cust_key, level2_account_id, level3_account_id, database_id) as (
select 1587, 245, 301, 21 from dual union all
select 1576, 289, 304, 20 from dual);
select get_accountdetails('[112].[22].[1]') from dual; -- result: 1123
select get_accountdetails('[289].[20].[2]') from dual; -- result: 1576
select get_accountdetails('[301].[21].[3]') from dual; -- result: 1587
Bitte verwenden Sie die richtigen Spaltennamen, die Sie in Ihren echten Daten haben, und passen Sie bei Bedarf Variablentypen und -längen an. Ich denke, Sie könnten auch eine verbundene Abfrage verwenden, es ist keine spezielle Funktion erforderlich, so etwas wie unten. Ich habe full join verwendet , da Ihre Beispiele keine übereinstimmenden Zeilen enthalten. Wahrscheinlich einfaches join wird ausreichen.
with t(par_input) as (select '[112].[22].[1]' from dual)
select dim_cust_key
from dim_cust_acnt a
full join dim_cust_dept d using (dim_cust_key)
cross join t
where ( 1 = regexp_substr(par_input, '\d+', 1, 3)
and regexp_substr(par_input, '\d+', 1, 1) = level1_account_id
and regexp_substr(par_input, '\d+', 1, 2) = a.database_id )
or ( 2 = regexp_substr(par_input, '\d+', 1, 3)
and regexp_substr(par_input, '\d+', 1, 1) = level2_account_id
and regexp_substr(par_input, '\d+', 1, 2) = d.database_id )
or ( 3 = regexp_substr(par_input, '\d+', 1, 3)
and regexp_substr(par_input, '\d+', 1, 1) = level3_account_id
and regexp_substr(par_input, '\d+', 1, 2) = d.database_id )
Ergebnis:
DIM_CUST_KEY
------------
1123
Wenn Sie with entfernen und cross join Teile und füge into hinzu -Klausel können Sie diese Abfrage in der Funktion anstelle von if verwenden Aussage.
Bearbeiten:
Entschuldigung für die Verspätung, ich habe mir Stack Overflow in letzter Zeit nicht angesehen. Hier sind zwei Beispiele, wie Sie Ihre Funktionen schreiben:
Diese Funktion gibt eine verkettete Zeichenfolge zurück:
select get_details_1('[112].[22].[1],[289].[20].[2],[301].[21].[3]') as list from dual;
LIST
------------------
1123,1576,1587
Und die zweite Funktion wird per Pipeline verarbeitet und gibt Daten als vordefinierte Sammlung von Zeichenfolgen zurück, sodass sich die Werte in separaten Zeilen befinden.
select column_value
from table(get_details_2('[112].[22].[1],[289].[20].[2],[301].[21].[3]'));
COLUMN_VALUE
------------
1123
1576
1587
Sie können auch zuerst alle Eingabedaten analysieren, sie in einer Sammlung speichern und dann die Massenerfassung in einer Abfrage verwenden. Es gibt viele Lösungen und Möglichkeiten, ich persönlich würde eine Pipeline-Funktion verwenden, aber es hängt davon ab, welche Form der Ausgabe Sie benötigen (Sammlung oder verkettete Zeichenfolge). Sie können auch begin ... end hinzufügen Ausnahme when no_data_found blockieren und behandeln . Sie können dann spezielle Informationen präsentieren oder die Ausführung unterbrechen, es hängt davon ab, welches Verhalten in einer solchen Situation erwartet wird.
Funktion 1:
create or replace function get_details_1 (par_input in varchar2) return varchar2 is
v_aid varchar2(10);
v_db varchar2(10);
v_lvl varchar2(10);
v_ret varchar2(20);
v_all varchar2(200) := '';
i_cnt int := 0;
begin
loop
v_aid := regexp_substr(par_input, '\d+', 1, i_cnt + 1);
v_db := regexp_substr(par_input, '\d+', 1, i_cnt + 2);
v_lvl := regexp_substr(par_input, '\d+', 1, i_cnt + 3);
i_cnt := i_cnt + 3;
exit when v_aid is null;
select dim_cust_key
into v_ret
from dim_cust_acnt a
full join dim_cust_dept d using (dim_cust_key)
where (v_lvl = 1 and level1_account_id = v_aid and a.database_id = v_db)
or (v_lvl = 2 and level2_account_id = v_aid and d.database_id = v_db)
or (v_lvl = 3 and level3_account_id = v_aid and d.database_id = v_db);
v_all := v_all||','||v_ret;
end loop;
return ltrim(v_all, ',');
end;
Funktion 2:
create or replace function get_details_2 (par_input in varchar2)
return sys.odcinumberlist pipelined is
v_aid varchar2(10);
v_db varchar2(10);
v_lvl varchar2(10);
v_ret varchar2(20);
i_cnt int := 0;
begin
loop
v_aid := regexp_substr(par_input, '\d+', 1, i_cnt + 1);
v_db := regexp_substr(par_input, '\d+', 1, i_cnt + 2);
v_lvl := regexp_substr(par_input, '\d+', 1, i_cnt + 3);
i_cnt := i_cnt + 3;
exit when v_aid is null;
select dim_cust_key
into v_ret
from dim_cust_acnt a
full join dim_cust_dept d using (dim_cust_key)
where (v_lvl = 1 and level1_account_id = v_aid and a.database_id = v_db)
or (v_lvl = 2 and level2_account_id = v_aid and d.database_id = v_db)
or (v_lvl = 3 and level3_account_id = v_aid and d.database_id = v_db);
pipe row (v_ret);
end loop;
return;
end;
