So zeigen Sie die Ergebnisse einer Prozedur außerhalb davon in Oracle an

Um das gezeigte Verfahren zu testen, würden Sie Folgendes tun:

declare
  l_id hr_position.id%type;
  l_group_name hr_position.group_name%type;
  l_group_level hr_position.group_level%type;
begin
  drill_record_position('D', l_id, l_group_name, l_group_level);
  dbms_output.put_line(l_id ||':'|| l_group_name ||':'|| l_group_level);
end;
/

Aber das - oder genauer gesagt, Ihr Verfahren - funktioniert nur, wenn es in der Ergebnismenge der Abfrage genau eine Zeile für den übergebenen Werttyp gibt. Es scheint, dass Sie mehrere Zeilen zurückerwarten (was zu viele Zeilen erhalten würde), aber es könnte auch keine geben (was dazu führen würde, dass keine Daten gefunden werden).

Es scheint also wirklich so, als ob sich Ihre Frage darauf beziehen sollte, wie Sie Ihre Prozedur schreiben, damit sie mit einer der von Ihnen ausprobierten Abruf-/Testmethoden funktioniert.

Wenn Ihre Prozedur mehrere Zeilen zurückgeben muss, kann sie einen Ref-Cursor verwenden, z. B.:

create or replace procedure drill_record_position (
  p_record_type in varchar2,
  p_ref_cursor out sys_refcursor
)
as
begin
  open p_ref_cursor for
    select hr.id, hr.group_name, hr.group_level
    from hr_position hr
    join drill_position dp
    on hr.id = dp.id
    where dp.typevalue = p_record_type;
end drill_record_position;
/

was Sie dann testen könnten mit etwas wie:

declare
  l_ref_cursor sys_refcursor;
  l_id hr_position.id%type;
  l_group_name hr_position.group_name%type;
  l_group_level hr_position.group_level%type;
begin
  drill_record_position('D', l_ref_cursor);
  loop
    fetch l_ref_cursor into l_id, l_group_name, l_group_level;
    exit when l_ref_cursor%notfound;
    dbms_output.put_line(l_id ||':'|| l_group_name ||':'|| l_group_level);
  end loop;
  close l_ref_cursor;
end;
/

Sie können dies auch als Funktion tun, mit der Sie in Ihrer Anwendung möglicherweise einfacher arbeiten können:

-- drop procedure drill_record_position;

create or replace function drill_record_position (p_record_type in varchar2)
return sys_refcursor as
  l_ref_cursor sys_refcursor;
begin
  open l_ref_cursor for
    select hr.id, hr.group_name, hr.group_level
    from hr_position hr
    join drill_position dp
    on hr.id = dp.id
    where dp.typevalue = p_record_type;
  return l_ref_cursor;
end drill_record_position;
/

declare
  l_ref_cursor sys_refcursor;
  l_id hr_position.id%type;
  l_group_name hr_position.group_name%type;
  l_group_level hr_position.group_level%type;
begin
  l_ref_cursor := drill_record_position('D');
  loop
    fetch l_ref_cursor into l_id, l_group_name, l_group_level;
    exit when l_ref_cursor%notfound;
    dbms_output.put_line(l_id ||':'|| l_group_name ||':'|| l_group_level);
  end loop;
  close l_ref_cursor;
end;
/

Sie können dies auch mit Sammlungen und einer Pipeline-Funktion tun, was mehr Arbeit zum Einrichten bedeutet:

create type t_drill_obj as object (
   -- use your real data types...
  id number,
  group_name varchar2(10),
  group_level number
)
/

create type t_drill_tab as table of t_drill_obj
/

create or replace function drill_record_position (p_record_type in varchar2)
return t_drill_tab pipelined as
begin
  for l_row in (
    select t_drill_obj(hr.id, hr.group_name, hr.group_level) as obj
    from hr_position hr
    join drill_position dp
    on hr.id = dp.id
    where dp.typevalue = p_record_type
  )
  loop
    pipe row (l_row.obj);
  end loop;
  return;
end drill_record_position;
/

aber Sie könnten es als Teil einer anderen Abfrage aufrufen und bei Bedarf sogar mit dem Ergebnis verbinden:

select * from table(drill_record_position('D'));