SQL Server:Machen Sie alle GROSSBUCHSTABEN zu Groß-/Titelbuchstaben

Diese Funktion:

• „Großschreibung“ alle Wörter in GROSSBUCHSTABEN, die durch Leerzeichen getrennt sind
• lässt "Kleinbuchstaben" in Ruhe
• funktioniert auch bei nicht-englischen Alphabeten einwandfrei
• ist insofern portabel, als es keine ausgefallenen Funktionen neuerer SQL-Server-Versionen verwendet
• kann leicht geändert werden, um NCHAR und NVARCHAR für die Unicode-Unterstützung sowie jede beliebige Parameterlänge zu verwenden, die Sie für richtig halten
• Leerraumdefinition kann konfiguriert werden

CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
  DECLARE @i INT           -- index
  DECLARE @l INT           -- input length
  DECLARE @c NCHAR(1)      -- current char
  DECLARE @f INT           -- first letter flag (1/0)
  DECLARE @o VARCHAR(255)  -- output string
  DECLARE @w VARCHAR(10)   -- characters considered as white space

  SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
  SET @i = 1
  SET @l = LEN(@string)
  SET @f = 1
  SET @o = ''

  WHILE @i <= @l
  BEGIN
    SET @c = SUBSTRING(@string, @i, 1)
    IF @f = 1 
    BEGIN
     SET @o = @o + @c
     SET @f = 0
    END
    ELSE
    BEGIN
     SET @o = @o + LOWER(@c)
    END

    IF @c LIKE @w SET @f = 1

    SET @i = @i + 1
  END

  RETURN @o
END

Ergebnis:

dbo.ToProperCase('ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and      Some lower Ää Öö Üü Éé Øø Cc Ææ