So fragen Sie die Rollen des aktuellen Benutzers ab

Sie sollten keine veralteten Abwärtskompatibilitätsansichten verwenden (). Durchsuchen Sie diese Seite nach sysusers , zum Beispiel ). Stattdessen sollten Sie sys.database_principals und sys.database_role_members . Denken Sie daran, dass der aktuellen Verbindung möglicherweise Zugriff außerhalb des Bereichs der Datenbank gewährt wurde (z. B. werden diese leere Ergebnisse zurückgeben, wenn der Benutzer zufällig ein sysadmin ist in diesem Fall müssen ihnen keine explizite Rollenmitgliedschaft oder bestimmte Berechtigungen gewährt werden). Auch für explizit außerhalb des Bereichs einer Rolle zugewiesene Berechtigungen, die die von der Rolle bereitgestellten außer Kraft setzen, sollten Sie zusätzlich sys.database_permissions . Hier ist ein eigenständiges Beispiel, das Sie sich ansehen können (solange Sie noch kein Login namens blatfarA haben oder eine Datenbank namens floob ).

CREATE LOGIN blatfarA WITH PASSWORD = 'foo', CHECK_POLICY = OFF;
GO
CREATE DATABASE floob;
GO
USE floob;
GO
CREATE USER blatfarB FROM LOGIN [blatfarA] WITH DEFAULT_SCHEMA = dbo;
GO
GRANT SELECT, UPDATE ON SCHEMA::dbo TO blatfarB;
DENY INSERT, EXECUTE ON SCHEMA::dbo TO blatfarB;
GO
EXEC sp_addrolemember N'db_datareader', N'blatfarB'
GO

Um es zu testen:

EXECUTE AS LOGIN = N'blatfarA';
GO

DECLARE @login NVARCHAR(256), @user NVARCHAR(256);

SELECT @login = login_name FROM sys.dm_exec_sessions WHERE session_id = @@SPID;

SELECT @user = d.name
  FROM sys.database_principals AS d
  INNER JOIN sys.server_principals AS s
  ON d.sid = s.sid
  WHERE s.name = @login;

SELECT u.name, r.name
  FROM sys.database_role_members AS m
  INNER JOIN sys.database_principals AS r
  ON m.role_principal_id = r.principal_id
  INNER JOIN sys.database_principals AS u
  ON u.principal_id = m.member_principal_id
  WHERE u.name = @user;

SELECT class_desc, major_id, permission_name, state_desc
  FROM sys.database_permissions
  WHERE grantee_principal_id = USER_ID(@user);

GO
REVERT;

Ergebnisse:

name      name
--------  -------------
blatfarB  db_datareader

class_desc  major_id  permission_name  state_desc
----------  --------  ---------------  ----------
DATABASE    0         CONNECT          GRANT
SCHEMA      1         INSERT           DENY
SCHEMA      1         EXECUTE          DENY
SCHEMA      1         SELECT           GRANT
SCHEMA      1         UPDATE           GRANT

Aufräumen:

USE master;
GO
ALTER DATABASE floob SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
GO
DROP DATABASE floob;
GO
DROP LOGIN blatfarA;
GO