Transaktionsebene und gespeicherte Prozeduren von SQL Server 2005

Die gespeicherte Prozedur verwendet beim Aufruf die geltende Transaktionsisolation.

Wenn die gespeicherte Prozedur selbst eine explizite Isolationsstufe festlegt, wird diese zurückgesetzt, wenn die gespeicherte Prozedur beendet wird.

(Bearbeiten:Gerade überprüft und das ist im Gegensatz zu dem, was BOL sagt "... es bleibt für diese Verbindung gesetzt, bis es explizit geändert wird", kann aber unten gesehen werden)

CREATE PROC CheckTransLevel
AS
DECLARE @Result varchar(20)

SELECT @Result = CASE transaction_isolation_level 
                        WHEN 0 THEN 'Unspecified' 
                        WHEN 1 THEN 'ReadUncomitted' 
                        WHEN 2 THEN 'Readcomitted' 
                        WHEN 3 THEN 'Repeatable' 
                        WHEN 4 THEN 'Serializable' 
                        WHEN 5 THEN 'Snapshot' 
                  END 
FROM sys.dm_exec_sessions 
WHERE session_id = @@SPID

PRINT @Result

GO
CREATE PROC SetRCTransLevel
AS
PRINT 'Enter: SetRCTransLevel'
SET TRANSACTION ISOLATION LEVEL READ COMMITTED
EXEC CheckTransLevel
PRINT 'Exit: SetRCTransLevel'
GO

SET NOCOUNT ON

SET TRANSACTION ISOLATION LEVEL READ UNCOMMITTED

EXEC CheckTransLevel

EXEC SetRCTransLevel

EXEC CheckTransLevel

Ergebnisse

ReadUncomitted
Enter: SetRCTransLevel
Readcomitted
Exit: SetRCTransLevel
ReadUncomitted