Oracle
 sql >> Datenbank >  >> RDS >> Oracle

Wie bekomme ich eine Datei von BLOB in Oracle?

In diesem Lernprogramm erfahren Sie, wie Sie eine Datei aus der BLOB-Spalte in Oracle abrufen. Um ein Beispiel zu geben, habe ich eine Tabelle EXT_FILES in Oracle erstellt und es folgt die Struktur der Tabelle.

CREATE TABLE EXT_FILES
(
FILE_NAME VARCHAR2(1000 BYTE),
FILE_CONTENT BLOB
)
/

Fügen Sie die Daten in die obige Tabelle ein. Wenn Sie nicht wissen, wie Sie eine Datei in eine BLOB-Spalte einfügen, sehen Sie sich den folgenden Artikel How To Insert A File in Oracle Table BLOB Column?

an

Sie müssen ein Oracle-Verzeichnisobjekt in Ihrem Schema erstellt haben, um die Dateien aus der BLOB-Spalte auf die Festplatte zu übertragen. Um ein Verzeichnis in Oracle zu erstellen, geben Sie den folgenden Befehl ein.

CREATE OR REPLACE DIRECTORY IMGDIR AS 'C:\TEMP\IMAGES';

Unten ist das Oracle Stored Procedure-Beispiel, das die Datensätze aus der EXT_FILES-Tabelle (die BLOB-Daten enthält) mit einem Cursor abruft und dann die Dateien einzeln in das angegebene Verzeichnis extrahiert.

Oracle Stored Procedure Beispiel zum Abrufen der Datei aus der BLOB-Spalte in Oracle

CREATE OR REPLACE PROCEDURE get_files_from_blob
IS
l_file UTL_FILE.file_type;
l_buffer RAW (32767);
l_amount BINARY_INTEGER := 32767;
l_pos INTEGER := 1;
l_blob_len INTEGER;
l_blob BLOB;
l_filename ext_files.file_name%TYPE;
/* cursor to get the records from the table */
CURSOR c_files
IS
SELECT file_name, file_content FROM ext_files;
BEGIN
OPEN c_files;

LOOP

FETCH c_files
INTO l_filename, l_blob;

EXIT WHEN c_files%NOTFOUND;

l_blob_len := DBMS_LOB.getlength (l_blob);

/* Change the directory name (IMGDIR) to your Oracle directory object name*/
l_file :=
UTL_FILE.fopen ('IMGDIR',
l_filename,
'wb',
32767);
l_pos := 1;

WHILE l_pos < l_blob_len
LOOP
DBMS_LOB.read (l_blob,
l_amount,
l_pos,
l_buffer);
UTL_FILE.put_raw (l_file, l_buffer, TRUE);
l_pos := l_pos + l_amount;
END LOOP;

UTL_FILE.fclose (l_file);
END LOOP;

CLOSE c_files;
EXCEPTION
WHEN OTHERS
THEN
IF UTL_FILE.is_open (l_file)
THEN
UTL_FILE.fclose (l_file);
END IF;

RAISE;
END;

Test

BEGIN
get_files_from_blob;
END;
/

Ausgabe

PL/SQL procedure successfully completed.

Sie können jetzt den Speicherort des IMGDIR-Verzeichnisobjekts für die extrahierten Dateien überprüfen.

Siehe auch:

  • Extrahieren Sie BLOB-Daten aus der Oracle-Tabelle mit Toad