Wie validiere ich die Kreditkartennummer und identifiziere ihren Typ mit PL/SQL?

Hier gebe ich ein Beispiel für eine gespeicherte PL/SQL-Funktion, um die Kreditkartennummer zu validieren und ihren Typ zu identifizieren, ob es sich um eine Visa-, MasterCard- oder American Express-Kreditkarte handelt. Ich überprüfe die Kreditkartennummer mit dem LUHN-Algorithmus, der zur Validierung einer Vielzahl von Identifikationsnummern verwendet wird. Wenn die Kreditkartennummer gültig ist, prüft die Funktion auf ihren Typ.

PL/SQL-Funktionsbeispiel zur Validierung der Kreditkartennummer und ihres Typs in Oracle

Die folgende Funktion nimmt ein Argument als Kreditkartennummer und validiert dann die Nummer mit dem Luhn-Algorithmus und gibt ihren Typ zurück. Derzeit unterstützt diese PL/SQL-Funktion drei Arten von Kreditkarten:Visa, MasterCard und American Express. Sie können ändern, um weitere Kreditkartentypen hinzuzufügen. Die Funktion CHECK_LUHN_ALGO zum Überprüfen der Nummer mit dem Luhn-Algorithmus ist in die Funktion VALIDATE_CC geschrieben. Wenn Sie also die Unterstützung weiterer Kartentypen hinzufügen möchten, müssen Sie die Funktion CHECK_LUHN_ALGO nicht ändern, ändern Sie nur den Hauptteil der Funktion VALIDATE_CC.

CREATE OR REPLACE FUNCTION validate_CC (cc_number IN VARCHAR2)
   RETURN VARCHAR2
IS
   v_ret_string   VARCHAR2 (100);

   FUNCTION check_luhn_algo (p_ccnumber VARCHAR2)
      RETURN NUMBER
   IS
      i          NUMBER;
      n_ntoi     SMALLINT;
      n_retval   SMALLINT;
      n_calc     NUMBER := 0;
      n_ntoc     NUMBER;
   BEGIN
      n_ntoc := LENGTH (p_ccnumber);

      FOR i IN 1 .. n_ntoc
      LOOP
         n_ntoi := TO_NUMBER (SUBSTR (p_ccnumber, n_ntoc + 1 - i, 1));

         n_calc :=
              n_calc
            + MOD (i, 2) * n_ntoi
            + MOD (i + 1, 2) * SIGN (-SIGN (n_ntoi - 4) + 1) * (2 * n_ntoi)
            +   MOD (i + 1, 2)
              * SIGN (SIGN (n_ntoi - 5) + 1)
              * (2 * n_ntoi - 9);
      END LOOP;

      n_retval := SIGN (MOD (n_calc, 10));

      RETURN n_retval;
   EXCEPTION
      WHEN OTHERS
      THEN
         RETURN 1;
   END check_luhn_algo;
BEGIN
   /* Credit card number is invalid if below funciton returns non zero value */
   IF check_luhn_algo (cc_number) != 0
   THEN
      v_ret_string := 'Not a valid Credit Card Number.';
      RETURN v_ret_string;
   ELSE
      v_ret_string := 'A Valid ';
   END IF;

   /* Credit card number is valid now check for its type */

   IF SUBSTR (cc_number, 1, 1) = '4'          /* check if it is a Visa card */
   THEN
      IF LENGTH (cc_number) = 13 OR LENGTH (cc_number) = 16
      THEN
         v_ret_string := v_ret_string || 'Visa Credit Card Number.';
      END IF;
   ELSIF SUBSTR (cc_number, 1, 2) BETWEEN 51 AND 55  /* check if master card*/
   THEN
      IF LENGTH (cc_number) = 16
      THEN
         v_ret_string := v_ret_string || 'MasterCard Credit Card Number.';
      END IF;
   ELSIF SUBSTR (cc_number, 1, 2) = 34 OR SUBSTR (cc_number, 1, 2) = 37 /* check if amex card */
   THEN
      IF LENGTH (cc_number) = 15
      THEN
         v_ret_string :=
            v_ret_string || 'American Express Credit Card Number.';
      END IF;
   ELSE
      v_ret_string := v_ret_string || 'But unable to identify its type.';
   END IF;

   RETURN v_ret_string;
EXCEPTION
   WHEN OTHERS
   THEN
      RETURN 'Error...';
END validate_CC;

Test

Ändern Sie zum Testen die Zeichenfolge 4047xxxxxxxxxxxx unten durch Ihre Visa-, MasterCard- oder Amex-Kreditkartennummer.

SET SERVEROUTPUT ON;

DECLARE
   RetVal      VARCHAR2 (100);
   CC_NUMBER   VARCHAR2 (100);
BEGIN
   CC_NUMBER := '4047xxxxxxxxxxxx';

   RetVal := VALIDATE_CC (CC_NUMBER);
   DBMS_OUTPUT.put_line (retval);
END;
/

Ausgabe

A Valid Visa Credit Card Number.
PL/SQL procedure successfully completed.

Hinweis: Testen Sie gründlich, bevor Sie in Ihrer Anwendung implementieren.

Siehe auch:

• E-Mail-Adresse mit PL/SQL in Oracle validieren