4 Beispiele für anonyme PL/SQL-Blöcke

In diesem Tutorial gebe ich 4 Beispiele für anonyme PL/SQL-Blöcke, damit Sie lernen können, wie man anonyme Blöcke in der Oracle-Datenbank erstellt und verwendet. Anonyme Blöcke in PL/SQL sind Programme, die keine Create Procedure- oder Create Function-Anweisung haben und nicht in der Oracle-Datenbank gespeichert werden. Anonyme PL/SQL-Blöcke, die hauptsächlich zum Testen oder zum einmaligen Ausführen des Programms in der Oracle-Datenbank verwendet werden.

1. Anonymer PL/SQL-Block zum Drucken von Zahlen in umgekehrter Reihenfolge

Das folgende PL/SQL-Programm gibt die Zahlen 0 bis 10 in umgekehrter Reihenfolge aus, wobei die REVERSE-Klausel in der for-Schleife verwendet wird.

SET SERVEROUTPUT ON;
DECLARE
  counter   NUMBER;
BEGIN
  FOR counter IN REVERSE 0..10 LOOP
    DBMS_OUTPUT.PUT_LINE (counter);
  END LOOP;
END;
/

Ausgabe

10
9
8
7
6
5
4
3
2
1
0
PL/SQL procedure successfully completed.

2. Anzahl der Mitarbeiter in einer Abteilung drucken

Das folgende PL/SQL-Programm zählt die Mitarbeiter in Abteilung 90. Die Tabelle stammt aus dem HR-Schema der Oracle-Datenbank. Sie können dieses Schema über den folgenden Link Download HR Schema herunterladen.

SET SERVEROUTPUT ON;

DECLARE
   emp_count         NUMBER;
   v_department_id   NUMBER := 90;
BEGIN
   SELECT COUNT ( * )
     INTO emp_count
     FROM employees
    WHERE department_id = v_department_id;

   DBMS_OUTPUT.PUT_LINE(   'The employee count is: '
                        || emp_count
                        || ' for the department with an ID of: '
                        || v_department_id);
END;
/

Ausgabe

The employee count is: 3 for the department with an ID of: 90
PL/SQL procedure successfully completed.

3. Nehmen Sie Eingaben in PL/SQL Anonymous Block and Print auf

Im folgenden Beispiel wird der Benutzer nach der Abteilungs-ID gefragt und die Mitarbeiterzahl in dieser Abteilung sowie der Abteilungsname gedruckt.

SET SERVEROUTPUT ON;

DECLARE
   dept_id_var   NUMBER (4) := &department_id;
   dept_name     VARCHAR2 (30);
   emp_count     NUMBER;
BEGIN
   SELECT COUNT ( * )
     INTO emp_count
     FROM employees
    WHERE department_id = dept_id_var;

   SELECT department_name
     INTO dept_name
     FROM departments
    WHERE department_id = dept_id_var;

   DBMS_OUTPUT.PUT_LINE(   'There are '
                        || emp_count
                        || ' employees '
                        || 'in the '
                        || dept_name
                        || ' department.');
END;
/

Ausgabe

Enter value for department_id: 60
old   2:   dept_id_var  NUMBER(4) := &department_id;
new   2:   dept_id_var  NUMBER(4) := 60;
There are 4 employees in the IT department.

PL/SQL procedure successfully completed.

4. PL/SQL-Block mit <> Beispiel

Der folgende PL/SQL-Block verwendet die Bezeichnungen für übergeordnete und untergeordnete Blöcke. Der untergeordnete Block greift auf die Variable des übergeordneten Blocks zu, indem er die Label-Referenz des übergeordneten Blocks verwendet. Das Programm aktualisiert die alte Manager-ID mit der neuen Manager-ID für die Abteilungen.

SET SERVEROUTPUT ON;
<<outer_block>>
DECLARE
   mgr_id       NUMBER (6) := '&current_manager_id';
   dept_count   NUMBER := 0;
BEGIN
   SELECT COUNT ( * )
     INTO dept_count
     FROM departments
    WHERE manager_id = outer_block.mgr_id;

   IF dept_count > 0
   THEN
     <<inner_block>>
      DECLARE
         dept_name   VARCHAR2 (30);
         mgr_id      NUMBER (6) := '&new_manager_id';
      BEGIN
         SELECT department_name
           INTO dept_name
           FROM departments
          WHERE manager_id = outer_block.mgr_id;

         UPDATE departments
            SET manager_id = inner_block.mgr_id
          WHERE manager_id = outer_block.mgr_id;

         DBMS_OUTPUT.PUT_LINE (
            'Department manager ID has been changed for ' || dept_name);
      END inner_block;
   ELSE
      DBMS_OUTPUT.PUT_LINE (
         'There are no departments listed for the manager');
   END IF;
EXCEPTION
   WHEN NO_DATA_FOUND
   THEN
      DBMS_OUTPUT.PUT_LINE (
         'There are no departments listed for the manager');
END outer_block;
/

Ausgabe

Enter value for current_manager_id: 100
old 3: mgr_id NUMBER (6) := '&current_manager_id';
new 3: mgr_id NUMBER (6) := '100';
Enter value for new_manager_id: 201
old 16: mgr_id NUMBER (6) := '&new_manager_id';
new 16: mgr_id NUMBER (6) := '201';
Department manager ID has been changed for Executive

PL/SQL procedure successfully completed.