Möglichkeiten zur Vermeidung globaler temporärer Tabellen in Oracle

"Kann jemand zeigen, wie man die obigen Beispielabfragen in Sammlungen und/oder Cursor umwandelt?"

Die von Ihnen geposteten Abfragen können zu einer einzigen Anweisung zusammengeführt werden:

SELECT case when a.column_a IS NULL OR a.column_a = ' ' 
           then b.data_a
           else  column_a end AS someA,
       a.someB,
       a.someC
FROM TABLE_A a
      left outer join TABLE_B b
          on ( a.column_b = b.data_b AND a.column_c = 'C' )
WHERE condition_1 = 'YN756'
  AND type_cd = 'P'
  AND TO_NUMBER(TO_CHAR(m_date, 'MM')) = '12'
  AND (lname LIKE (v_LnameUpper || '%') OR
  lname LIKE (v_searchLnameLower || '%'))
  AND (e_flag = 'Y' OR
  it_flag = 'Y' OR
  fit_flag = 'Y'));

(Ich habe Ihre Logik einfach umgesetzt, aber dieser case() -Anweisung könnte durch ein übersichtlicheres nvl2(trim(a.column_a), a.column_a, b.data_a) ersetzt werden ).

Ich weiß, dass Sie sagen, dass Ihre Abfragen komplizierter sind, aber Ihre erste Anlaufstelle sollte sein, sie umzuschreiben. Ich weiß, wie verführerisch es ist, eine knorrige Abfrage in viele Baby-SQLs zu zerlegen, die mit PL/SQL zusammengefügt werden, aber reines SQL ist viel effizienter.

Um eine Sammlung zu verwenden, ist es am besten, die Typen in SQL zu definieren, da uns dies die Flexibilität gibt, sie sowohl in SQL-Anweisungen als auch in PL/SQL zu verwenden.

create or replace type tab_a_row as object
    (col_a number
     , col_b varchar2(23)
     , col_c date);
/
create or replace type tab_a_nt as table of tab_a_row;
/

Hier ist eine Beispielfunktion, die eine Ergebnismenge zurückgibt:

create or replace function get_table_a 
      (p_arg in number) 
      return sys_refcursor 
is 
    tab_a_recs tab_a_nt; 
    rv sys_refcursor; 
begin 
    select tab_a_row(col_a, col_b, col_c)  
    bulk collect into tab_a_recs 
    from table_a 
    where col_a = p_arg; 

    for i in tab_a_recs.first()..tab_a_recs.last() 
    loop 
        if tab_a_recs(i).col_b is null 
        then 
            tab_a_recs(i).col_b :=  'something'; 
        end if; 
    end loop;  

    open rv for select * from table(tab_a_recs); 
    return rv; 
end; 
/ 

Und hier ist es in Aktion:

SQL> select * from table_a
  2  /

     COL_A COL_B                   COL_C
---------- ----------------------- ---------
         1 whatever                13-JUN-10
         1                         12-JUN-10

SQL> var rc refcursor
SQL> exec :rc := get_table_a(1)

PL/SQL procedure successfully completed.

SQL> print rc

     COL_A COL_B                   COL_C
---------- ----------------------- ---------
         1 whatever                13-JUN-10
         1 something               12-JUN-10

SQL>

In der Funktion ist es notwendig, den Typ mit den Spalten zu instanziieren, um die Ausnahme ORA-00947 zu vermeiden. Dies ist beim Füllen eines PL/SQL-Tabellentyps nicht erforderlich:

SQL> create or replace procedure pop_table_a
  2        (p_arg in number)
  3  is
  4      type table_a_nt is table of table_a%rowtype;
  5      tab_a_recs table_a_nt;
  6  begin
  7      select *
  8      bulk collect into tab_a_recs
  9      from table_a
 10      where col_a = p_arg;
 11  end;
 12  /

Procedure created.

SQL> 

Zum Schluss Richtlinien