Es gibt zwei Verwendungen für RAISE_APPLICATION_ERROR. Die erste besteht darin, generische Oracle-Ausnahmemeldungen durch unsere eigenen, aussagekräftigeren Meldungen zu ersetzen. Die zweite besteht darin, eigene Ausnahmebedingungen zu erstellen, wenn Oracle sie nicht auslösen würde.
Das folgende Verfahren veranschaulicht beide Verwendungen. Es erzwingt eine Geschäftsregel, dass in Zukunft keine neuen Mitarbeiter mehr eingestellt werden können. Es überschreibt auch zwei Oracle-Ausnahmen. Einer ist DUP_VAL_ON_INDEX, der von einem eindeutigen Schlüssel auf EMP(ENAME) geworfen wird . Die andere ist eine benutzerdefinierte Ausnahme, die ausgelöst wird, wenn der Fremdschlüssel zwischen EMP(MGR) und EMP(EMPNO) verletzt wird (weil ein Manager ein bestehender Mitarbeiter sein muss).
create or replace procedure new_emp
( p_name in emp.ename%type
, p_sal in emp.sal%type
, p_job in emp.job%type
, p_dept in emp.deptno%type
, p_mgr in emp.mgr%type
, p_hired in emp.hiredate%type := sysdate )
is
invalid_manager exception;
PRAGMA EXCEPTION_INIT(invalid_manager, -2291);
dummy varchar2(1);
begin
-- check hiredate is valid
if trunc(p_hired) > trunc(sysdate)
then
raise_application_error
(-20000
, 'NEW_EMP::hiredate cannot be in the future');
end if;
insert into emp
( ename
, sal
, job
, deptno
, mgr
, hiredate )
values
( p_name
, p_sal
, p_job
, p_dept
, p_mgr
, trunc(p_hired) );
exception
when dup_val_on_index then
raise_application_error
(-20001
, 'NEW_EMP::employee called '||p_name||' already exists'
, true);
when invalid_manager then
raise_application_error
(-20002
, 'NEW_EMP::'||p_mgr ||' is not a valid manager');
end;
/
Wie es aussieht:
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate+1)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate+1); END;
*
ERROR at line 1:
ORA-20000: NEW_EMP::hiredate cannot be in the future
ORA-06512: at "APC.NEW_EMP", line 16
ORA-06512: at line 1
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 8888, sysdate)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 8888, sysdate); END;
*
ERROR at line 1:
ORA-20002: NEW_EMP::8888 is not a valid manager
ORA-06512: at "APC.NEW_EMP", line 42
ORA-06512: at line 1
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate)
PL/SQL procedure successfully completed.
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate); END;
*
ERROR at line 1:
ORA-20001: NEW_EMP::employee called DUGGAN already exists
ORA-06512: at "APC.NEW_EMP", line 37
ORA-00001: unique constraint (APC.EMP_UK) violated
ORA-06512: at line 1
Beachten Sie die unterschiedliche Ausgabe der beiden Aufrufe von RAISE_APPLICATION_ERROR im EXCEPTIONS-Block. Das Setzen des optionalen dritten Arguments auf TRUE bedeutet, dass RAISE_APPLICATION_ERROR die auslösende Ausnahme in den Stapel einschließt, was für die Diagnose hilfreich sein kann.
Weitere nützliche Informationen finden Sie im PL/SQL-Benutzerhandbuch.
