Sammlungen manipulieren

Zumindest haben Sie im zweiten Fall eine Tabellendefinition verloren. Diese Anweisung:

create or replace TYPE tbl_list2 IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));

deklariert nur den Objekt- (oder Datensatz-) Typ, keine Tabelle.

Sie müssen es also in 2 Schritten tun:

create or replace TYPE tbl_list_rec IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));
/

create or replace TYPE tbl_list2 as table of tbl_list_rec;
/

Danach benötigen Sie einige Syntaxkorrekturen im Skript:

declare
  l_object tbl_list2;
  i        number;
begin
  -- for list initialization it must be filled with constructed objects
  l_object := tbl_list2( tbl_list_rec('','') );

  for i in 1..100000 loop          

    -- 1. select values to variable
    -- 2. Fix constructor for list 
    select 
      l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
    into 
      l_object 
    from 
      dual;

    end loop;

    for i in l_object.first ..  l_object.last loop
      -- output separate fields, there are now default conversion from 
      -- user-defined objects to varchar2.
      dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
    end loop;  

end;
/

AKTUALISIEREN

Die obige Lösung ist aufgrund der großen Anzahl von Kontextwechseln relativ langsam. Aber der Vergleich von Instanzen komplexer Objekttypen kann ohne zusätzliche Arbeit nicht direkt in PL/SQL durchgeführt werden.
Damit Oracle wissen kann, ob Objektinstanzen gleich oder unterschiedlich sind, müssen wir Zuordnungs- oder Sortiermethode für Objekttyp . Beide Arten von Methoden sind nicht zulässig, daher muss die richtige ausgewählt werden. MAP-Methoden sind schneller und in unserem Fall ist keine Bestellung erforderlich, also machen Sie es:

create or replace TYPE tbl_list_rec2 AS OBJECT (
  l_owner  VARCHAR2(64),
  l_name  VARCHAR2(64),
  map member function get_key return varchar2
);
/

Implementierung:

create or replace TYPE BODY tbl_list_rec2 AS 

  map member function get_key return varchar2
  is
  begin
    return l_owner||chr(1)||l_name;
  end;

end;
/

Danach ist es möglich, Objekte in PL/SQL-Code auf Gleichheit zu testen, wie einfaches varchar2 im ersten Beispiel aus Frage:

declare
  l_object tbl_list2a;
  i        number; 
begin
  l_object := tbl_list2a( tbl_list_rec2('','') );

  for i in 1..100000 loop          
    l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
  end loop;

  for i in l_object.first..  l_object.last loop
    dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
  end loop;  

end;
/