Machen Sie dafür keine Schleifen innerhalb von Schleifen in PL/SQL - verwenden Sie SQL, um Ihnen die gebrauchsfertigen Daten zu geben.
Zuerst erstellen wir Ihre Tabelle mit einigen Testdaten (ich schätze Datentypen - Sie ersetzen sie durch Ihre eigenen):
create table product_master (
product_no varchar2(10)
, product_holder varchar2(10)
, product_catalogue varchar2(10)
)
/
insert into product_master values ('1', 'SMITH', 'TEMP')
/
insert into product_master values ('2', 'SMITH', 'TEMP')
/
insert into product_master values ('3', 'HARRY', 'ARCH')
/
insert into product_master values ('4', 'TOM' , 'DEPL')
/
commit
/
Was wir an mail_send senden möchten Verfahren für jeden product_holder ist eine Sammlung (Array), die product_no enthält und product_catalogue . Also zuerst ein Typ, der diese beiden Elemente enthält:
create type t_prod_cat_no as object (
product_no varchar2(10)
, product_catalogue varchar2(10)
)
/
Und dann ein verschachtelter Tabellentyp (Sammlungstyp) dieses Typs:
create type t_prod_cat_no_table as
table of t_prod_cat_no
/
Die Prozedur mail_send sollte dann den product_holder akzeptieren und den Sammlungstyp:
create or replace procedure mail_send (
p_parameter in varchar2
, p_product_holder in varchar2
, p_product_cats_nos in t_prod_cat_no_table
)
is
begin
dbms_output.put_line('-- BEGIN '||p_parameter||' --');
dbms_output.put_line('Dear '||p_product_holder);
dbms_output.put_line('Your products are:');
for i in 1..p_product_cats_nos.count loop
dbms_output.put_line(
'Catalogue: '||p_product_cats_nos(i).product_catalogue||
' - No: '||p_product_cats_nos(i).product_no
);
end loop;
end mail_send;
/
(Ich verwende einfach dbms_output, um den Aufbau einer Mail zu simulieren.)
Dann können Sie in SQL eine group by product_holder durchführen und lassen Sie SQL die Sammlung generieren, die die Daten enthält:
begin
for holder in (
select pm.product_holder
, cast(
collect(
t_prod_cat_no(pm.product_no,pm.product_catalogue)
order by pm.product_catalogue
, pm.product_no
) as t_prod_cat_no_table
) product_cats_nos
from product_master pm
group by pm.product_holder
order by pm.product_holder
) loop
mail_send(
'PRODMASTER'
, holder.product_holder
, holder.product_cats_nos
);
end loop;
end;
/
Die Ausgabe des obigen Blocks ist:
-- BEGIN PRODMASTER --
Dear HARRY
Your products are:
Catalogue: ARCH - No: 3
-- BEGIN PRODMASTER --
Dear SMITH
Your products are:
Catalogue: TEMP - No: 1
Catalogue: TEMP - No: 2
-- BEGIN PRODMASTER --
Dear TOM
Your products are:
Catalogue: DEPL - No: 4
Das geht in SQL mit einem GROUP BY gibt Ihnen alles in einem einzigen Aufruf von PL/SQL zu SQL, was viel effizienter ist als der erste Aufruf, um den eindeutigen Satz von product_holder zu erhalten , Schleife darüber und dann ein Aufruf pro product_holder um die Produkte für jeden Inhaber zu erhalten.
UPDATE:
order by hinzugefügt zum collect Funktion im obigen Code, um zu zeigen, dass Sie die Kontrolle über die Reihenfolge haben, in der die Daten in die Sammlung eingefügt werden.
