Bietet Oracle die Möglichkeit, mehrere Teilstrings aus einer geparsten String-/Clob-Zeile zurückzugeben?

So etwas vielleicht:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN sys.dbms_debug_vc2coll PIPELINED
IS  
  pos PLS_INTEGER;
  lastpos PLS_INTEGER;
  element varchar(2000);
BEGIN
   lastpos := 1;
   pos := instr(longline, ',');

   while pos > 0 loop
      element := substr(longline, lastpos, pos - lastpos);
      lastpos := pos + 1;
      pos := instr(longline, ',', lastpos);
      pipe row(element);
   end loop;

   if lastpos <= length(longline) then
      pipe row (substr(longline, lastpos));
   end if;

   RETURN;
END;  
/

Dies kann wie folgt verwendet werden:

SQL> select * from table(explode('1,2,3'));

COLUMN_VALUE
---------------------------------------------
1
2
3
SQL>

Wenn Sie nicht auf 11.x sind, müssen Sie den Rückgabetyp selbst definieren:

create type char_table as table of varchar(4000);

und ändern Sie die Funktionsdeklaration in:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN char_table pipelined
.....