SQL Server – Automatische Inkrementierung, die UPDATE-Anweisungen zulässt

Eine Lösung für dieses Problem finden Sie in „Inside Microsoft SQL Server 2008:T-SQL Querying“

CREATE TABLE dbo.Sequence(
 val int IDENTITY (10000, 1) /*Seed this at whatever your current max value is*/
 )

GO

CREATE PROC dbo.GetSequence
@val AS int OUTPUT
AS
BEGIN TRAN
    SAVE TRAN S1
    INSERT INTO dbo.Sequence DEFAULT VALUES
    SET @val=SCOPE_IDENTITY()
    ROLLBACK TRAN S1 /*Rolls back just as far as the save point to prevent the 
                       sequence table filling up. The id allocated won't be reused*/
COMMIT TRAN

Oder eine andere Alternative aus demselben Buch, die Bereiche einfacher zuweist. (Sie müssten überlegen, ob Sie dies von innerhalb oder außerhalb Ihrer Transaktion aufrufen - innerhalb würde andere gleichzeitige Transaktionen blockieren, bis die erste festgeschrieben wird)

CREATE TABLE dbo.Sequence2(
 val int 
 )

GO

INSERT INTO dbo.Sequence2 VALUES(10000);

GO

CREATE PROC dbo.GetSequence2
@val AS int OUTPUT,
@n as int =1
AS
UPDATE dbo.Sequence2 
SET @val = val = val + @n;

SET @val = @val - @n + 1;