Ja, verwenden Sie Tabellenwertparameter. Erstellen Sie zuerst einen Typ:
CREATE TYPE dbo.StudentIDs(ID INT PRIMARY KEY);
Jetzt kann Ihre Prozedur dies verwenden (beachten Sie, dass ich Ihren verschachtelten IN geändert habe Abfragen zu einem korrekten Join):
CREATE PROCEDURE dbo.MarkStudentsAsDeleted
@IDs dbo.StudentIDs READONLY
AS
BEGIN
SET NOCOUNT ON;
UPDATE s SET IsDeleted = 1
FROM dbo.Students AS s
INNER JOIN dbo.Class AS c
ON s.StudentId = c.StudentId
INNER JOIN dbo.ClassValueTable AS ct
ON c.PassId = ct.Id
WHERE ct.IsDeleted <> 1
AND EXISTS (SELECT 1 FROM @IDs WHERE StudentID = s.StudentID);
END
GO
Und Ihr C#-Code würde eine DataTable übergeben oder wie auch immer Sie die Sammlung von activeIds zusammengestellt haben, statt einer durch Kommas getrennten Liste.
DataTable dt = new DataTable();
dt.Columns.Add("ID", typeof(int));
dt.Rows.Add(1);
dt.Rows.Add(2);
dt.Rows.Add(3);
dt.Rows.Add(4);
... open connection etc. ...
SqlCommand cmd = new SqlCommand("dbo.MarkStudentsAsDeleted", conn);
cmd.CommandType = CommandType.StoredProcedure;
SqlParameter tvp1 = cmd.Parameters.AddWithValue("@IDs", dt);
tvp1.SqlDbType = SqlDbType.Structured;
cmd.ExecuteNonQuery();
... close, dispose, etc. ...
Wenn Sie darauf bestehen möchten, dass eine Zeichenfolge an die gespeicherte Prozedur übergeben wird, müssen Sie eine Split-Funktion verwenden. Zum Beispiel:
CREATE FUNCTION dbo.SplitInts
(
@List VARCHAR(MAX),
@Delimiter VARCHAR(255) = ','
)
RETURNS TABLE
WITH SCHEMABINDING
AS
RETURN
(
SELECT [value] = y.i.value('(./text())[1]', 'int')
FROM
(
SELECT x = CONVERT(XML, '<i>'
+ REPLACE(@List, @Delimiter, '</i><i>')
+ '</i>').query('.')
) AS a CROSS APPLY x.nodes('i') AS y(i)
);
GO
Jetzt kann Ihre gespeicherte Prozedur sein:
CREATE PROCEDURE dbo.MarkStudentsAsDeleted
@IDs VARCHAR(MAX)
AS
BEGIN
SET NOCOUNT ON;
UPDATE s SET IsDeleted = 1
FROM dbo.Students AS s
INNER JOIN dbo.Class AS c
ON s.StudentId = c.StudentId
INNER JOIN dbo.ClassValueTable AS ct
ON c.PassId = ct.Id
WHERE ct.IsDeleted <> 1
AND EXISTS (SELECT 1 FROM dbo.SplitInts(@IDs, ',') WHERE Item = s.StudentID);
END
GO
