Baumstrukturdatenabfrage in SQL Server

Ich glaube nicht, dass am Design etwas auszusetzen ist, vorausgesetzt, Sie haben ein begrenztes Maß an Eltern-Kind-Beziehungen. Hier ist ein kurzes Beispiel für das Abrufen der Beziehung mit einem rekursiven CTE:

USE tempdb;
GO

CREATE TABLE dbo.tree
(
    ID INT PRIMARY KEY,
    name VARCHAR(32),
    ParentID INT FOREIGN KEY REFERENCES dbo.tree(ID)
);

INSERT dbo.tree SELECT 1, 'grandpa', NULL
UNION ALL SELECT 2, 'dad', 1
UNION ALL SELECT 3, 'me', 2
UNION ALL SELECT 4, 'mom', 1
UNION ALL SELECT 5, 'grandma', NULL;

;WITH x AS
(
    -- anchor:
    SELECT ID, name, ParentID, [level] = 0
    FROM dbo.tree WHERE ParentID IS NULL
    UNION ALL
    -- recursive:
    SELECT t.ID, t.name, t.ParentID, [level] = x.[level] + 1
    FROM x INNER JOIN dbo.tree AS t
    ON t.ParentID = x.ID
)
SELECT ID, name, ParentID, [level] FROM x
ORDER BY [level]
OPTION (MAXRECURSION 32);
GO

Aufräumen nicht vergessen:

DROP TABLE dbo.tree;

Dies könnte ein nützlicher Artikel sein. Eine Alternative ist hierarchyid aber ich finde es für die meisten Szenarien zu komplex.