Wie überprüfe ich mit PL/SQL, ob die Datei ein Bild ist?

In diesem Blogbeitrag teile ich eine Funktion, mit der Sie überprüfen können, ob eine Datei eine Bilddatei ist oder nicht, indem Sie PL/SQL verwenden. Das Programm überprüft die Datei, indem es ihren Header und nicht den Erweiterungsnamen der Datei liest. Derzeit kann die Funktion drei Arten von Bildern erkennen:JPG, PNG und GIF.

PL/SQL-Funktion zum Prüfen, ob Datei eine Bilddatei ist

Die folgende PL/SQL-Funktion liest den Dateiheader und gibt dann den Bildtyp im Datentyp varchar2 zurück. Die Funktion get_image_type akzeptiert zwei Argumente, und zwar wie folgt:

1. Oracle-Verzeichnisobjekt (als i_dir) Erfahren Sie, wie Sie ein Oracle-Verzeichnisobjekt erstellen.
2. Dateiname (als i_file) Datei sollte im Verzeichnis existieren.

CREATE OR REPLACE FUNCTION get_image_type (i_dir    IN VARCHAR2,
                                           i_file   IN VARCHAR2)
   RETURN VARCHAR2
AS
   l_bfile       BFILE;
   l_blob        BLOB;
   l_file_type   VARCHAR2 (50);
BEGIN
   DBMS_LOB.createtemporary (l_blob, FALSE);
   l_bfile := BFILENAME (i_dir, i_file);
   DBMS_LOB.fileopen (l_bfile, DBMS_LOB.file_readonly);
   DBMS_LOB.loadfromfile (l_blob, l_bfile, DBMS_LOB.getlength (l_bfile));
   DBMS_LOB.fileclose (l_bfile);

   IF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 8, 1)) = '89504E470D0A1A0A'
   THEN
      l_file_type := 'PNG';
   ELSIF DBMS_LOB.SUBSTR (l_blob, 3, 1) = '474946'
   THEN
      l_file_type := 'GIF';
   ELSIF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 3, 1)) = 'FFD8FF'
   THEN
      l_file_type := 'JPG';
   ELSE
      l_file_type := 'The file is not an image.';
   END IF;

   RETURN l_file_type;
EXCEPTION
   WHEN OTHERS
   THEN
      IF DBMS_LOB.fileisopen (l_bfile) = 1
      THEN
         DBMS_LOB.fileclose (l_bfile);
      END IF;

      DBMS_LOB.freetemporary (l_blob);
      RETURN 'The file does not exists.';
END get_image_type;

Test

Ersetzen Sie im folgenden PL/SQL-Programm das Oracle-Verzeichnisobjekt MY_FILES durch Ihr Verzeichnisobjekt und ändern Sie den Dateinamen durch die Datei, die am Speicherort des Verzeichnisses MY_FILES verfügbar ist.

SET SERVEROUTPUT ON;

DECLARE
   i_image_type   VARCHAR2 (50);
BEGIN
   i_image_type := get_image_type ('MY_FILES', 'oracle-logo-gif-to-use.gif');

   IF i_image_type IN ('JPG', 'GIF', 'PNG')
   THEN
      DBMS_OUTPUT.put_line ('The file is a valid ' || i_image_type || ' image.');
   ELSE
      DBMS_OUTPUT.put_line (i_image_type);
   END IF;
END;
/

Ausgabe

The file is a valid GIF image.
PL/SQL procedure successfully completed.

Siehe auch:

• Wie füge ich mit PL/SQL eine Datei in eine Oracle-Tabelle ein?