Wie speichere ich BLOB als Datei in PL/SQL?

Hier gebe ich ein Beispiel zum Speichern von BLOB-Daten als Datei in PL/SQL. BLOB-Daten können Sie aus der Tabelle mit der BLOB-Spalte oder aus einer Datei auf der Festplatte abrufen.

PL/SQL-Funktionsbeispiel zum Speichern von BLOB als Datei

Die folgende Prozedur akzeptiert die folgenden drei Argumente:

1. Name des Oracle-Verzeichnisobjekts (als i_dir).
2. Speichern unter Dateiname (als i_file).
3. BLOB-Daten (als i_blob).

CREATE OR REPLACE PROCEDURE blob_to_file (i_dir    IN VARCHAR2,
                                          i_file   IN VARCHAR2,
                                          i_blob   IN BLOB)
AS
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
BEGIN
   l_blob_len := DBMS_LOB.getlength (i_blob);

   l_file :=
      UTL_FILE.fopen (i_dir,
                      i_file,
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP
      DBMS_LOB.read (i_blob,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (l_file)
      THEN
         UTL_FILE.fclose (l_file);
      END IF;

      RAISE;
END blob_to_file;

Test

Der folgende PL/SQL-Block ruft die obige Prozedur auf, indem er das Oracle-Verzeichnisobjekt, den Dateinamen und die BLOB-Daten übergibt. Für die BLOB-Daten verwende ich die GET_BLOB-Funktion, für die ich in meinem vorherigen Blogbeitrag ein Beispiel gegeben habe:Get BLOB from a File in PL/SQL. Im folgenden Fall werden die BLOB-Daten aus einer Datei myfile.jpg vom Speicherort MY_DIR abgerufen und in der Datei abc.jpg am Speicherort IMG_DIR gespeichert.

DECLARE
   f_blob   BLOB;
BEGIN
   /* check the above mentioned link for get_blob function example */
   f_blob := get_blob ('MY_DIR', 'myfile.jpg');
   /* now pass the blob to blob_to_file procedure to save it as a file */
   blob_to_file ('IMG_DIR', 'abc.jpg', f_blob);
END;

Jetzt können Sie den Speicherort des IMG_DIR-Verzeichnisses für die durch BLOB erstellte Datei überprüfen.

Siehe auch:

• Wie erstelle ich ein Oracle-Verzeichnisobjekt?
• Erfahren Sie, wie Sie mit Toad BLOB-Daten aus Oracle-Tabellen extrahieren