Oracle:Kann ich programmgesteuert feststellen, ob eine Prozedur ein Commit enthält?

Ich habe eine Paketprozedur, die ich dafür geschrieben habe. Ich füge den Code unten ein.

Um es zu verwenden, rufen Sie einfach "start_no_commit_section" mit einem von Ihnen angegebenen Namen auf. Rufen Sie dann später "end_no_commit_section" mit demselben Namen auf. Wenn ein Commit (oder Rollback) ausgegeben wurde, löst der Aufruf von "end_no_commit_section" einen Fehler aus.

Leider sagt Ihnen das nicht wo das Commit ist passiert. Wenn ich eine Menge Code durchsehen muss, lasse ich im Allgemeinen DBMS_HPROF auf meinem Code laufen und suche dann in den HPROF-Ergebnissen nach einem Commit (das mir die genaue Zeilennummer mitteilt).

  CREATE OR REPLACE PACKAGE BODY XXCUST_TRANSACTION_UTIL AS
  ----------------------------------------------------------------
  -- See package spec for comments
  ----------------------------------------------------------------
  TYPE no_commit_section_t IS RECORD (local_transaction_id VARCHAR2 (200));

  TYPE no_commit_sections_tab IS TABLE OF no_commit_section_t
                                   INDEX BY VARCHAR2 (80);

  g_no_commit_sections   no_commit_sections_tab;

  PROCEDURE start_no_commit_section (p_section_name VARCHAR2) IS
    l_section   no_commit_section_t;
  BEGIN
    l_section.local_transaction_id                          := DBMS_TRANSACTION.local_transaction_id (create_transaction => TRUE);
    g_no_commit_sections (SUBSTR (p_section_name, 1, 80))   := l_section;
  END start_no_commit_section;


  PROCEDURE end_no_commit_section (p_section_name VARCHAR2) IS
    l_local_transaction_id   VARCHAR2 (200);
  BEGIN
    l_local_transaction_id   := DBMS_TRANSACTION.local_transaction_id (create_transaction => TRUE);

    IF l_local_transaction_id != g_no_commit_sections (SUBSTR (p_section_name, 1, 80)).local_transaction_id THEN
      -- There has been a commit or a rollback in the no-commit section
      raise_application_error(-20001,'A commit or rollback has been detected in "No commit" section ' || p_section_name || '.');
    END IF;
  EXCEPTION
    WHEN no_data_found THEN
      -- Caller specified a non-existent commit section
      raise_application_error(-20001,'"No commit" section ' || p_section_name || ' not established.');
  END end_no_commit_section;
END XXCUST_TRANSACTION_UTIL;