Ist es möglich, mit JDBC aus der ANYDATA Synchronous Capture-Warteschlange zu entfernen?

Sie könnten eine gespeicherte Prozedur schreiben und die Nachricht in PL/SQL aus der Warteschlange entfernen und sie in XML-Text konvertieren und als CLOB zurückgeben. Dann können Sie die gespeicherte Prozedur von Java mit JDBC aufrufen. Ich habe zuvor eine ähnliche Problemumgehung verwendet, als der einfachen AQ-API eine Funktion fehlte.

Beispiel:

create or replace procedure dequeue_lcr(
    p_queue_name   varchar2,
    p_consumer     varchar2,
    p_wait_seconds number,
    p_lcr          out clob) as
  deq_lcr     anydata;
  deq_xml     xmltype;
  msgid       raw(16); 
  deqopt      dbms_aq.dequeue_options_t; 
  mprop       dbms_aq.message_properties_t;
  no_messages exception; 
  pragma exception_init (no_messages, -25228);
begin
  deqopt.consumer_name := p_consumer;
  deqopt.wait := p_wait_seconds;
  deqopt.navigation := dbms_aq.first_message;
  deqopt.dequeue_mode  := dbms_aq.remove;
  begin
    dbms_aq.dequeue( 
      queue_name         =>  p_queue_name,
      dequeue_options    =>  deqopt,
      message_properties =>  mprop,
      payload            =>  deq_lcr,
      msgid              =>  msgid);
     deq_xml := dbms_streams.convert_lcr_to_xml(deq_lcr);
     p_lcr := deq_xml.getclobval();    
     commit;
  exception
    when no_messages then
      p_lcr := null;
  end;
end;

Dies funktioniert, wenn ich es von PL/SQL aus mit der richtigen Warteschlange und dem richtigen Verbraucher aufrufe:

declare
  v_clob clob;
begin
  dequeue_lcr('aqtest.hcb_queue_any', 'LOCAL_AGENT', 5, v_clob);
  if (v_clob is not null) then
    dbms_output.put_line('Data: ' || v_clob);
  else
    dbms_output.put_line('No messages');  
  end if;
end;

Machen Sie einfach den Aufruf von Java mit einem CallableStatement mit einem Clob als Ausgabeparameter und Sie sollten loslegen!