Oracle PL/SQL:Daten aus einer Tabelle in CSV exportieren

Erfahren Sie, wie Sie die UTL_FILE verwenden Paket zum Exportieren von Daten aus einer Tabelle in die CSV-Datei in Oracle PL/SQL.

In Oracle das Paket UTL_FILE enthält viele Prozeduren und Funktionen zum Schreiben einer Textdatei. Nachfolgend finden Sie die Syntaxdetails und die notwendigen Schritte zum Schreiben einer Datei:

Syntax und Schritte zum Schreiben einer Datei mit UTL_FILE

-- Declare a variable to store file type
n_file UTL_FILE.FILE_TYPE;
-- Open the file in Begin section, it will open the file and return the file handle into the variable n_file
n_file := UTL_FILE.FOPEN('DIR_OBJ', 'YourCSVFileName.csv', 'w', 4000);
-- Write a single or multiple lines
UTL_FILE.PUT_LINE(n_file, 'abc, xyz, xxx');
-- Close the file
UTL_FILE.FCLOSE(n_file);

Einfaches Beispiel

Declare
   n_file Utl_File.File_Type;
Begin
   -- The directory object MY_DIR must be exist or create a new one
   n_file := Utl_File.Fopen('MY_DIR', 'myfile.csv', 'w', '4000');

   Utl_File.Put_Line(n_file, 'First line.');
   Utl_File.Put_Line(n_file, 'Second line.');
   Utl_File.Put_Line(n_file, 'Third line.');

   Utl_File.Fclose(n_file);
End;

Wie ich im obigen Beispiel erwähnt habe, ist das Verzeichnisobjekt MY_DIR muss vorhanden sein. Das Verzeichnisobjekt in Oracle ist ein Verweis auf das physische Verzeichnis auf dem Server. Das Folgende ist ein Beispiel für das Erstellen eines Verzeichnisobjekts in Oracle:

-- Windows example
CREATE OR REPLACE DIRECTORY CSVDIR AS 'd:\oracle\csvfiles';
-- Linux example
CREATE OR REPLACE DIRECTORY CSVDIR AS '/usr1/oracle/csvfiles';

Um mehr über das Verzeichnisobjekt in Oracle zu erfahren, überprüfen Sie diesen Link.

Daten aus einer Tabelle in CSV im Oracle-Beispiel exportieren

Das Folgende ist ein Beispiel für eine gespeicherte Prozedur in Oracle, die die Daten aus der EMP-Tabelle in eine CSV-Datei exportiert:

Create Or Replace Procedure exp_emp_data Is

    n_file     utl_file.file_type;
    v_string   Varchar2(4000);
   
  -- get the data using cursor 
  Cursor c_emp Is
    Select
        empno,
        ename,
        deptno,
        sal,
        comm
    From
        emp;

Begin
    n_file := utl_file.fopen('CSVDIR', 'empdata.csv', 'w', 4000);

-- if you do not want heading then remove below two lines
    v_string := 'Emp Code, Emp Name, Dept, Salary, Commission';
    utl_file.put_line(n_file, v_string);
    
    -- open the cursor and concatenate fields using comma
    For cur In c_emp Loop
        v_string := cur.empno
                    || ','
                    || cur.ename
                    || ','
                    || cur.deptno
                    || ','
                    || cur.sal
                    || ','
                    || cur.comm;
        
        -- write each row
        utl_file.put_line(n_file, v_string);
    End Loop;
    
    -- close the file
    utl_file.fclose(n_file);
Exception
    When Others Then
        -- on error, close the file if open
        If utl_file.is_open(n_file) Then
            utl_file.fclose(n_file);
        End If;
End;

Nachdem Ihre gespeicherte Prozedur erstellt wurde, führen Sie sie aus, um die Daten zu exportieren:

Begin
    exp_emp_data;
End;

Verwandte Tutorials:

• Dienstprogramm:PL/SQL-Prozedur generieren, um Daten aus einer Tabelle zu exportieren