Hibernate-Verschlüsselung der Datenbank, vollständig transparent für die Anwendung

Wenn Sie die Arbeit in der Anwendung beenden, können Sie benutzerdefinierte Hibernate-Typen verwenden, und es würde nicht so viele Änderungen zu Ihrem Code hinzufügen.

Hier ist ein verschlüsselter benutzerdefinierter Zeichenfolgentyp, den ich verwendet habe:

import org.hibernate.usertype.UserType
import org.apache.log4j.Logger

import java.sql.PreparedStatement
import java.sql.ResultSet
import java.sql.SQLException
import java.sql.Types

class EncryptedString implements UserType {

  // prefix category name with 'org.hibernate.type' to make logging of all types easier
  private final Logger _log = Logger.getLogger('org.hibernate.type.com.yourcompany.EncryptedString')

  Object nullSafeGet(ResultSet rs, String[] names, Object owner) throws SQLException {
    String value = rs.getString(names[0])

    if (!value) {
      _log.trace "returning null as column: $names[0]"
      return null
    }

    _log.trace "returning '$value' as column: $names[0]"
    return CryptoUtils.decrypt(value)
  }

  void nullSafeSet(PreparedStatement st, Object value, int index) throws SQLException {
    if (value) {
      String encrypted = CryptoUtils.encrypt(value.toString())
      _log.trace "binding '$encrypted' to parameter: $index"
      st.setString index, encrypted
    }
    else {
      _log.trace "binding null to parameter: $index"
      st.setNull(index, Types.VARCHAR)
    }
  }

  Class<String> returnedClass() { String }

  int[] sqlTypes() { [Types.VARCHAR] as int[] }

  Object assemble(Serializable cached, Object owner) { cached.toString() }

  Object deepCopy(Object value) { value.toString() }

  Serializable disassemble(Object value) { value.toString() }

  boolean equals(Object x, Object y) { x == y }

  int hashCode(Object x) { x.hashCode() }

  boolean isMutable() { true }

  Object replace(Object original, Object target, Object owner) { original }
}

und basierend darauf sollte es einfach sein, ähnliche Klassen für int, long usw. zu erstellen. Um es zu verwenden, fügen Sie den Typ zum Mapping-Abschluss hinzu:

class MyDomainClass {

  String name
  String otherField

  static mapping = {
    name type: EncryptedString
    otherField type: EncryptedString
  }
}

Ich habe die Methoden CryptoUtils.encrypt() und CryptoUtils.decrypt() weggelassen, da dies nicht Grails-spezifisch ist. Wir verwenden AES, z. "Cipher cipher =Cipher.getInstance('AES/CBC/PKCS5Padding')". Was auch immer Sie am Ende verwenden, stellen Sie sicher, dass es eine 2-Wege-Krypto ist, d. h. verwenden Sie nicht SHA-256.